Help with 2D Pong Game

[Kyle]

Hey,

First of all, I just learned QBASIC this year in a programming class at my high school, and we now have 1 month to make a program. I knew how to do every thing i got typed so far except the keyboard input code to make paddle move up and down which i had to find and edit and make work. But pretty much I need help with a couple things.

1. How to make ball move and stuff.

2. How to make other paddle have AI like try to stay on the same Y line as the ball.

3. More of a question, is there a way i can make two players where the 2nd player uses O and L to move, and have both paddles move at same time. EX: I could only get it to let player 1 and 2 keep tapping the keys because as soon as 1 player held a key down to make paddle keep moving the other player could not move his paddle. please answer.

Here is the code, and input, code, full code, snippets, or addvice would be nice. I got till end of May.

REM KYLE
REM FINAL
CLS
SCREEN 8

INPUT "WHAT IS YOUR NAME"; NAME1$ ' DISPLAYS INPUT ' CLEARS SCREEN
CLS
X = 5 ' VARIABLE FOR 5
Y = 80 ' VARIABLE FOR 80
X2 = 625 ' VARIABLE FOR 625
COLOR , 2 ' MAKES SCREEN GREEN
COLOR 15 ' MAKES SCORE TEXT BRIGHT WHITE
LOCATE 1, 1 ' LOCATE PLAYER NAME TOP LEFT
PRINT NAME1$; "'S SCORE" ' PRINTS PLAYER NAME TOP LEFT
LOCATE 1, 39 ' LOCATES COMPUTER NAME
PRINT "COMPUTER'S SCORE" ' PRINTS COMPUTER NAME
LINE (0, 8)-(640, 8), 7 ' DRAWS TOP LINE
LINE (0, 192)-(640, 192), 7 ' DRAWS BOTTOM LINE
LINE (300, 8)-(300, 192), 7 ' VERTICAL LINE DOWN CENTER
CIRCLE (300, 98), 100, 7 ' DRAWS CIRCLE IN CENTER OF TABLE
CIRCLE (300, 98), 10, 15 ' DRAWS THE BALL
PAINT (301, 96), 15, 15 ' PAINTS THE BALL
LINE (X, Y)-(X + 10, Y + 35), 15, BF ' PLAYER 1 PADDLE
LINE (X2, Y)-(X2 + 10, Y + 35), 15, BF ' PLAYER 2 PADDLE

DO ' PLAYER 1 PADDLE MOVEMENT
DO ' WAITS FOR KEYPRESS
KEYED$ = INKEY$
LOOP UNTIL KEYED$ <> ""
LINE (X, Y)-(X + 10, Y + 35), 2, BF ' DRAWS PADDLE
IF (KEYED$ = "Q") AND (Y > 10) THEN Y = Y - 5 ' MOVES PADDLE UP, PREVENTS PADDLE FROM LEAVING TOP
IF (KEYED$ = "A") AND (Y < 151) THEN Y = Y + 5 ' MOVES PADDLE DOWN, PREVENTS PADDLE FORM LEAVING BOTTOM
LINE (X, Y)-(X + 10, Y + 35), 15, BF ' REDRAWS PADDLE
LOOP ' LOOPS MOVEMENT

[Mikrondel]

My eyes. Help. My eyes.

Too many comments!

Ok, I understand that before you posted there was actually some horizontal gap between the code and the comments, but still, having a comment on practically every line is ridiculous.

Don't get me wrong, comments are a good thing to have. But don't go overboard. In particular, don't restate the obvious:

X = 5 ' VARIABLE FOR 5

If you're going to the trouble of a comment, make it say something more descriptive. Like maybe

X = 5 ' SET INITIAL X POSITION OF PADDLE


Onto your questions...

1. "How the make the ball move and stuff."

and stuff. Exactly. You're trying to do a few things at once. Is that possible? Well, let me tell you how Windows does it. It runs one program for a very short time, then it lets another program run for a very short time, then another, and so on; then it goes back to the first and lets it run some more, and then the second, and so forth.

To get a similar effect in your own program, all you need is to ensure that no part will hog the execution. At the moment, your
DO ' WAITS FOR KEYPRESS
KEYED$ = INKEY$
LOOP UNTIL KEYED$ <> "" does hog the execution. You don't want to do nothing while you wait for a key to be pressed, you have other things to attend to. So kick the loop, just turn it into an IF.

One other thing: the comment for
LINE (X, Y)-(X + 10, Y + 35), 2, BF ' DRAWS PADDLE
is not correct. That line erases the paddle.

Now, here's a rough plan of how a successful attempt might look:

DO

  Check the keyboard
  If a key is pressed, take appropriate action
  

  Erase ball
  Change ball's position (according to its speed)
  If ball is outside boundaries, adjust ball velocity and position [or give a point to a player]
  If ball is touching paddle, adjust ball velocity
  Draw ball in new position


  Delay for a short time


LOOP


Notice that nothing within the big DO-LOOP (apart from the delay at the end which keeps everything steady) calls on looping. Also, I left out what should be done according to the key presses (you had it pretty much right anyway) and that is to erase the paddle, update its position and draw it in the new position.

Also, for the AI part, you would just add another little section into the loop. But I'll leave that for you to have a go at.


And here's something vaguely related for you to look at if you choose, but it probably has stuff you are unfamiliar with.


SCREEN 7

TYPE Ball

X AS INTEGER
Y AS INTEGER
Xvel AS INTEGER
Yvel AS INTEGER

Col AS INTEGER 'Colour

END TYPE



DIM B(0 TO 63) AS Ball


RANDOMIZE TIMER

'Make the balls random
FOR I = 0 TO UBOUND(B)
B(I).X = INT(RND * 320)
B(I).Y = INT(RND * 200)

B(I).Xvel = INT(RND * 5) - 2
B(I).Yvel = INT(RND * 5) - 2

B(I).Col = INT(RND * 14) + 1
NEXT


DO

EndTime! = TIMER + .03
FOR I = 0 TO UBOUND(B)

 'Erase ball
 PSET (B(I).X, B(I).Y), 0

 'Move ball
 B(I).X = B(I).X + B(I).Xvel
 B(I).Y = B(I).Y + B(I).Yvel

 'Check ball is within borders; if not then move it and reverse its velocity
 IF B(I).X < 0 THEN B(I).X = -B(I).X: B(I).Xvel = -B(I).Xvel
 IF B(I).Y < 0 THEN B(I).Y = -B(I).Y: B(I).Yvel = -B(I).Yvel

 IF B(I).X > 319 THEN B(I).X = 319 + 319 - B(I).X: B(I).Xvel = -B(I).Xvel
 IF B(I).Y > 199 THEN B(I).Y = 199 + 199 - B(I).Y: B(I).Yvel = -B(I).Yvel

 'Draw ball
 PSET (B(I).X, B(I).Y), B(I).Col
NEXT

 'Wait to the end of .03 seconds
DO: LOOP WHILE TIMER < EndTime!

LOOP UNTIL LEN(INKEY$)




Now for your last question. Yes it's possible, but not with INKEY$. There are two possibilities. One is INP(&H60) or INP(96) - this basically reads from the keyboard port and tells you when a key is pressed or released. But you have to read it very often in case you miss something. A bit tricky. And more cryptic still is to install your own keyboard interrupt that maintains a table of which key is pressed and which isn't. Very effective and efficient, and relatively easy to use, but it requires quite a bit of code and if your program gets stuck in a loop, you can't get back to QB with ctrl-break.

www.network54.com/Forum/171757/message/1028686054/Here+is+an+interesting+multiple-key-press+function


Yes I think it will attract strage looks from your teacher. INP(96) at least doesn't involve putting big chunks of thing in your program.

Just try getting your 1-player pong working and if that's done and you have a little time to spare then I can give you more details.

Anyway, good luck and if you have any more questions then please let them be known.

[Kyle]

K, Thanks man, I will let you know if I need more help, and I will prolly need more help for sure on 2 players with the inp(96) stuff. BTW the comments in my code are like that because our teacher makes us do that, if it was up to me I wouldnt put that many, and it was a little more spread out in my code not right behind the code itself like that, but when i copyed and pasted, it pushed them to gether.

[Mikrondel]

No need to explain yourself; good teachers are hard to find. That's not to say that yours is bad, necessarily, because after all commenting is a good habit to get into.

See you around.

[Kyle]

Hey, I need help with ball movement code, I can only get the ball to move to the left of the screen at the start and when it gets to where i want it to stop and bouce back to right it just stops and sits there. Could anyone help me with ball movement code using the most basic commands you can use for it.

[Mikrondel]

All right, earlier I mentioned as one of your steps:
Change ball's position (according to its speed)
If ball is outside boundaries, adjust ball velocity and position [or give a point to a player]
If ball is touching paddle, adjust ball velocity

So you need to know what speed the ball is supposed to be moving at. And the best way to do that is by storing it in a variable.

Best results occur when you use one variable for the X velocity, and another for Y velocity. Each loop, you add the X velocity to the X position and the Y velocity to the Y position. If the ball hits the top or bottom, you just reverse the sign of the Y velocity (e.g. Yspeed = - Yspeed). If you hit a paddle, you want to reverse the X velocity (and perhaps also change the Y velocity depending on which part of the paddle you hit, so you can 'angle' the ball).

Since you're storing the speed in a variable, that's all there is to it; next time around the code that moves the ball will use the new value in the variable.

If you still have trouble, please provide your code as it makes it much easier for us to see what you need help with.

[Kyle]

Hey, I need some help implementing ball movement code, I cant seem to figure it out. Here is all the code to my program so far.

REM KYLE CONRAD
REM FINAL
CLS
SCREEN 8

MENU:
X = 195
Y = 140
CLS                                                  
COLOR , 1                                              
COLOR 7                                                
LINE (195, 20)-(430, 55), 7, BF                                                                              
LINE (215, 25)-(215, 50), 1                      
LINE (220, 25)-(240, 25), 1
LINE (240, 25)-(240, 35), 1
LINE (240, 35)-(220, 35), 1
LINE (260, 25)-(260, 50), 1                            
LINE (260, 25)-(285, 25), 1
LINE (285, 25)-(285, 50), 1
LINE (285, 50)-(260, 50), 1
LINE (305, 25)-(305, 50), 1                            
LINE (305, 25)-(330, 25), 1
LINE (330, 25)-(330, 50), 1
LINE (350, 25)-(350, 50), 1                            
LINE (350, 25)-(375, 25), 1
LINE (350, 50)-(375, 50), 1
LINE (375, 50)-(375, 40), 1
LINE (375, 40)-(360, 40), 1
LINE (395, 25)-(415, 25), 1                            
LINE (415, 25)-(405, 45), 1
LINE (405, 45)-(395, 25), 1
CIRCLE (405, 49), 4, 1                                  
LINE (50, 0)-(50, 200)                                  
LINE (590, 0)-(590, 200)                                
LINE (195, 37.5)-(50, 37.5)                            
LINE (430, 37.5)-(590, 37.5)                            
CIRCLE (X, Y), 8, 15                                  
PAINT (X + 1, Y + 1), 15, 15                            

DO                                                    
A$ = INKEY$                                            
SELECT CASE A$                                        
 CASE "1":                                            
 GOTO PONG1                                          
 CASE "2":                                            
 GOTO PONG2                                        
 CASE "3":                                            
 GOTO INSTRUCTIONS                                    
 CASE "4":                                            
 END                                                
END SELECT                                            
LOCATE 10, 32                                          
PRINT "1) ONE PLAYER"                                  
LOCATE 11, 32                                          
PRINT "2) TWO PLAYERS"                                
LOCATE 12, 32                                          
PRINT "3) INSTRUCTIONS"                            
LOCATE 13, 32                                          
PRINT "4) EXIT"                                        
LOCATE 14, 32                                          
PRINT "MAKE YOUR SELECTION"
LOOP                                                  

END                                                    

'--------------------------------------------------

PONG1:                                                  

CLS                                                    
INPUT "WHAT IS YOUR NAME"; NAME1$                      

CLS                                                    
X = 5                                                  
Y = 85                                                  
X2 = 625                                              
Y2 = 85                                                
X3 = 310                                                
Y3 = 98                                                
YSPEED = 1
XSPEEDL = 1
XSPEEDR = -1
COLOR , 2                                              
COLOR 15                                              
LOCATE 1, 1                                            
PRINT NAME1$; "'S SCORE"                              
LOCATE 1, 40                                          
PRINT "COMPUTER'S SCORE"                            
LINE (0, 8)-(640, 8), 7                              
LINE (0, 192)-(640, 192), 7                            
LINE (310, 8)-(310, 192), 7                            
CIRCLE (310, 98), 100, 7                              
CIRCLE (X3, Y3), 5, 15                                  
PAINT (X3 + 1, Y3 + 1), 15, 15                          
LINE (X, Y)-(X + 10, Y + 25), 15, BF                  
LINE (X2, Y2)-(X2 + 10, Y2 + 25), 15, BF                

DO                                                    
A$ = INKEY$                                            
K% = INP(96)                                            
SELECT CASE K%                                        
 CASE 1: SYSTEM                                    
 CASE 16:                                              
  IF (Y > 10) THEN                                    
  LINE (X, Y)-(X + 10, Y + 25), 2, BF                
  Y = Y - 1                                          
  LINE (X, Y)-(X + 10, Y + 25), 15, BF                
  END IF                                              
 CASE 30:                                              
  IF (Y < 165) THEN                                    
  LINE (X, Y)-(X + 10, Y + 25), 2, BF              
  Y = Y + 1                                            
  LINE (X, Y)-(X + 10, Y + 25), 15, BF                
  END IF                                              
 END SELECT                                          

  IF X3 < X2 THEN                                    
  CIRCLE (X3, Y3), 5, 2                              
  PAINT (X3 + 1, Y3 + 1), 2, 2                        
  X3 = X3 - XSPEEDL
  CIRCLE (X3, Y3), 5, 15
  PAINT (X3 + 1, Y3 + 1), 15, 15
  END IF

  IF X3 <= X + 15 THEN
  CIRCLE (X3, Y3), 5, 2                              
  PAINT (X3 + 1, Y3 + 1), 2, 2                        
  X3 = X3 - XSPEEDR
  CIRCLE (X3, Y3), 5, 15
  PAINT (X3 + 1, Y3 + 1), 15, 15
  END IF
 
 
WAIT &H3DA, 8                                          
WAIT &H3DA, 8, 8
LOOP                                                  

'-------------------------------------------------
PONG2:                                                

CLS
INPUT "WHAT IS PLAYER ONE'S NAME"; NAME1$              
INPUT "WHAT IS PLAYER TWO'S NAME"; NAME2$

CLS                                                    
X = 5                                                  
Y = 85                                                  
X2 = 625                                                
Y2 = 85                                                
X3 = 310                                              
Y3 = 98                                                
COLOR , 2                                            
COLOR 15
LOCATE 1, 1                                          
PRINT NAME1$; "'S SCORE"                                
LOCATE 1, 40                                            
PRINT NAME2$; "'S SCORE"                                
LINE (0, 8)-(640, 8), 7                                
LINE (0, 192)-(640, 192), 7                            
LINE (310, 8)-(310, 192), 7                            
CIRCLE (310, 98), 100, 7                              
CIRCLE (X3, Y3), 5, 15                                
PAINT (X3 + 1, Y3 + 1), 15, 15                        
LINE (X, Y)-(X + 10, Y + 25), 15, BF                    
LINE (X2, Y2)-(X2 + 10, Y2 + 25), 15, BF              

DO                                                    
A$ = INKEY$                                            
K% = INP(96)                                          
SELECT CASE K%                                        
 CASE 1: SYSTEM                                        
 CASE 16:                                            
  IF (Y > 10) THEN                                    
   LINE (X, Y)-(X + 10, Y + 25), 2, BF                
   Y = Y - 1                                          
   LINE (X, Y)-(X + 10, Y + 25), 15, BF                
  END IF                                              
 CASE 30:                                            
  IF (Y < 165) THEN                                    
   LINE (X, Y)-(X + 10, Y + 25), 2, BF                
   Y = Y + 1                                          
   LINE (X, Y)-(X + 10, Y + 25), 15, BF              
  END IF                                              
 CASE 24:                                              
  IF (Y2 > 10) THEN                                  
   LINE (X2, Y2)-(X2 + 10, Y2 + 25), 2, BF          
   Y2 = Y2 - 1                                        
   LINE (X2, Y2)-(X2 + 10, Y2 + 25), 15, BF          
  END IF                                              
 CASE 38:                                              
  IF (Y2 < 165) THEN                                  
   LINE (X2, Y2)-(X2 + 10, Y2 + 25), 2, BF            
   Y2 = Y2 + 1                                        
   LINE (X2, Y2)-(X2 + 10, Y2 + 25), 15, BF          
  END IF                                              
END SELECT                                            
WAIT &H3DA, 8                                          
WAIT &H3DA, 8, 8
LOOP                                                

END

'----------------------------------------------------

INSTRUCTIONS:
CLS
COLOR 6
LOCATE 2, 30
PRINT "INSTRUCTIONS SCREEN"
LINE (230, 5)-(385, 5)
LINE (230, 17)-(385, 17)
LOCATE 4, 1
COLOR 7
PRINT "IN PONG YOU MOVE THE PADDLE UP AND DOWN ";
PRINT "AND TRY TO GET THE BALL PAST THE OTHER";
PRINT "PADDLE."
LOCATE 7, 30
COLOR 6
PRINT "*ONE PLAYER CONTROLS*"
LOCATE 9, 36
COLOR 7
PRINT "Q - UP"
LOCATE 10, 36
PRINT "A - DOWN"
COLOR 6
LOCATE 12, 30
PRINT "*TWO PLAYER CONTROLS*"
COLOR 2
LOCATE 14, 36
PRINT "PLAYER 1"
COLOR 7
LOCATE 16, 36
PRINT "Q - UP"
LOCATE 17, 36
PRINT "A - DOWN"
COLOR 2
LOCATE 19, 36
PRINT "PLAYER 2"
COLOR 7
LOCATE 21, 36
PRINT "O - UP"
LOCATE 22, 36
PRINT "L - DOWN"

Sorry for using goto subs but thats how our teacher taught us, Its not to scattered its pretty organized. So far Ive started on the ball movement for 1 player under pong1:, right now the ball moves to the left and stops where I want it to bounce back. I was gonna make it so the paddle was devide in 5 sections, 2 on the ends that make the ball bounce like 45 degrees up and down, 2 sections between middle and ends that make it bounce like 70 degree up and down and 1 in the middle that bounces the ball straight forward. Im not sure if you understand or if you do, im not sure if thats the best way but thats what I had in mind.

[Mikrondel]

Yuck. While your teacher probably isn't a nutcase, this programming style is seriously outdated and rather limiting. Many programmers will berate you for having a single GOTO.

Quick advice; use LINE with B (rather than BF) to draw a box that isn't filled in (handy for the O in PONG and maybe a few other places).

Now, where did your comments go? You've gone from obesity to anorexia! (no offence to people with eating disorders intended)
If you don't want to include comments then make your variable names more informative.


Now, onto the actual problem:

You're not following the structure I suggested. Let's look at:
Erase ball
 Change ball's position (according to its speed)
 If ball is outside boundaries, adjust ball velocity and position [or give a point to a player]
 If ball is touching paddle, adjust ball velocity
 Draw ball in new position

Now - there is only one Xspeed variable. Every loop, Xspeed is added to X. It's that simple.

In consequence, a positive Xspeed means the ball will move to the right, and a negative Xspeed means it will move to the left.


I just said "Every loop, Xspeed is added to X". That means, this step cannot be inside an IF-THEN. Neither can the Erase and Draw steps (that's according to the plan above). Think about it - the ball keeps moving no matter what. It shouldn't move only IF something is true. Occasionally the direction of movement will change - THAT part can go in an IF.

(Don't forget that every loop you also need to add YSpeed to Y.)


The problem with what you have now is that you
X3 = X3 - XSPEEDR
only IF the ball is touching the left paddle.

Alright, so that moves the ball away again - it's not touching the left paddle anymore; so the above bit doesn't happen anymore: the ball stops moving to the right. And a different part of the code is trying to move the ball left, so that is why it gets stuck.


Have one more try; remember that the only time you need IFs is to check if the ball is touching either paddle, or is going past the boundaries. In these cases all you do (for the moment) is change the direction of the ball's movement. (I.e. change XSpeed or YSpeed). Inside the IFs, you do not need to do any changes to X or Y, nor do any CIRCLEs or PAINTs.


Hopefully that'll help you work everything out. After you've finished, if you're interested, I can give you a hand on better ways to lay out your programs to make them easier to write, debug and modify.

[Kyle]

Ok ill give it another shot.

[earlofqb]

Yeah, GOSUB hasn't been used in years. Unless you're running some odd flavour of BASIC (meaning that being on a QBasic forum probably isn't the best thing for you, as the syntax differences can get weird depending on your flavour), use subroutines with void (or null) (or no, if you don't want to be "cool" and use hacker lingo) arguments.

Anyway, a big thing I'd do now is modularize the code some. Sure, it works well now, and all that; but isn't debugging it a pain? Instead of copying the code for the "one player" and "two player" modes, why not make a subroutine, and call it in different ways depending on how it's being used?

Now, if you don't fully understand what I'm saying, just ignore me. At this point, it's far more important that you finish the program (albeit with some confusing syntax), and get it running completely than if you worry about how easy it is to read and modify (or even optimizing your loops and all that to improve efficiency).

[Ildûrest]

earlofqb said:

Yeah, GOSUB hasn't been used in years.

By whom? I use it now and then. And it would be a good idea in this particular situation.

The problem here is the GOTOs. Again, I use them once in a while. But only when they have a clear advantage over all other options - this is not one of those times. In fact there is pretty much always a way to avoid GOTOs, and until you know how to do things that way, it's best to keep away from GOTO so you don't get bad habits.

The problem with GOTOs is simple: they're hard to follow. Yes, at the moment in your program they're actually easy to understand. But what happens when you want to go back to the menu after a game? Or go to a high scores table from the 1 player game, but not the rest? Well, admittedly it would still be manageable (Pong is not the best example of what I'm trying to explain). But the more complex your program, the more trouble you'll have trying to follow it, if it uses GOTOs to get around.

The theory of GOSUBs (and the SUB and FUNCTION procedures that Earl was talking about - I wouldn't worry about them yet) is basically that you give a name to a block of code, and other parts of your program can run that block then keep going. And the key is: you don't surrender control of the program to the new block of code, it's more like lending it.

Anyway, you should finish the program as it is, and perhaps when that's done we can explain how it would be written in a more maintainable and modular way.

[Kyle]

Ok I will post an update on my progress in prolly a few days, I got the ball moving and bouncing off paddles and top and bottom. I will post something if I need help before getting it done and touched up.

[earlofqb]

Well, when would you use a GOSUB?

[Ildûrest]

Kyle - I suggest you don't read this post. It might put you off programming


Earl - When the situation calls for it. Sure SUBs/FUNCTIONs have many (sometimes unneeded) advantages over GOSUB-RETURNs. But GOSUB can do one thing that SUBs/FUNCTIONs can't: access the calling procedure's local variables.


GNU C has something equivalent, called a "nested function". These can only be called from within the function that they are defined in.

Two reasons I can think of to use such things are:
- Something that needs to be done repeatedly throughout a procedure but has to modify many of that procedure's variables (a nested function is a lot more efficient and easier to read and maintain than passing 10 variables by reference to a normal function each time you call).
- Simple function scoping: if a function is only ever going to be called by one other function then it might make your program cleaner to take it out of global scope. (Especially if you have 20 such functions and they only make sense to be called out of a single function)

One time I used these was for an asynchronous-input parser. Every time I needed a new character (which happened in many places in the function, because of multi-character combinations), I would call the function, which needed to wait for more characters, adjust by buffer by the amount of new characters, and do error checking in case of a socket termination.

In any case, GOSUBs are somewhat easier to understand than SUBs/FUNCTIONs and help people get used to modularising code. Once they have the hang of it, you show them how much easier SUBs/FUNCTIONs can make things.

[kici]

hey man, I used Basic in 1999, Than i just stopped using it, and the computer. Now im back in form, learned some php, started C, html, and im a pro in mIRC , I own my own network, so, yeah, I hope when i stuck somewhere in
the qbasic programing, that you'll help me, but i also like Delphi 7 too it looks good for me and yeah that's it

[kici]

Kay Kyle, I just started this qbasic programing :P, but here is a demo which i have made in basic, its a game (but the ball moves all sides :D) it actually flyes :D

here it is:

'===========================================================================
' Subject: NEW ASSEMBLY MULTIKEY FUNCTION Date: 12-20-97 (10:33)
' Author: Joe Huber, Jr. Code: QB, QBasic, PDS
' Origin: Milo Sedlacek Packet: KEYBOARD.ABC
'===========================================================================
DECLARE SUB TheDemo ()
DECLARE SUB KEYTEST ()
DECLARE FUNCTION MULTIKEY (T)

'ASM Interrupt & support code by Milo Sedlacek
'Everything else by Joe Huber, Jr.
'(Following short startup program and minor program formatting"
' by Mac from the www.qbasic.com Forum)"
'Send any qustions, comments, etc. to: [e-mail]

CLS
PRINT "To run a demo program wherein a little ball is controlled"
PRINT "by the arrow keys, hit '1'"
PRINT
PRINT "To see all scan codes and witness that multiple keystrokes"
PRINT "are being detected, hit '2'"
PRINT
PRINT "At all times, quit program by <Esc>"
PRINT
DO
LOCATE , , 1: PRINT "Hit key now: ";
DO: k$ = INKEY$: LOOP WHILE k$ = ""
SELECT CASE k$
CASE "1": CALL TheDemo: RUN
CASE "2": CALL KEYTEST: RUN
CASE CHR$(27): CLS : SYSTEM
CASE ELSE: PRINT "Goof"
END SELECT
LOOP
STOP: 'Never gets here

'KB Interrrupt source
' &HE9,&H1D,&H00 : '0000 JMP 0020 ;Jump to INSTALL INTERRUPT
' &HE9,&H3C,&H00 : '0003 JMP 0042 ;Jump to UNINSTALL INTERRUPT
' &H00,&H00 : '0006 ADD [BX+SI],AL ;\
' &H00,&H00 : '0008 ADD [BX+SI],AL ; \
' &H00,&H00 : '000A ADD [BX+SI],AL ; } Unused space
' &H00,&H00 : '000C ADD [BX+SI],AL ; /
' &H00,&H00 : '000E ADD [BX+SI],AL ;/
' &H00,&H00 : '0010 ADD [BX+SI],AL ;variable: keyboard_matrix_segment
' &H00,&H00 : '0012 ADD [BX+SI],AL ;variable: keyboard_matrix_offset
' &H00,&H00 : '0014 ADD [BX+SI],AL ;variable: dos_isr_handler_offset
' &H00,&H00 : '0016 ADD [BX+SI],AL ;variable: dos_isr_handler_segment
' &H00,&H00 : '0018 ADD [BX+SI],AL ;\
' &H00,&H00 : '001A ADD [BX+SI],AL ; \
' &H00,&H00 : '001C ADD [BX+SI],AL ; / Unused space
' &H00,&H00 : '001E ADD [BX+SI],AL ;/
' &H1E : '0020 PUSH DS ;INSTALL INTERRUPT save DS for QBASIC
' &H31,&HC0 : '0021 XOR AX,AX ;\
' &H8E,&HD8 : '0023 MOV DS,AX ; } DS:SI -> interrupt vector 9
' &HBE,&H24,&H00 : '0025 MOV SI,0024 ;/
' &H0E : '0028 PUSH CS ;
' &H07 : '0029 POP ES ;ES = CS
' &HBF,&H14,&H00 : '002A MOV DI,0014 ;ES:DI -> dos_isr_handler_offset
' &HFC : '002D CLD ;Increment SI, DI on string moves
' &HA5 : '002E MOVSW ;\
' &HA5 : '002F MOVSW ;/ Read address of old handler
' &H8C,&HC3 : '0030 MOV BX,ES ;BX = CS
' &H8E,&HC0 : '0032 MOV ES,AX ;ES = 0
' &HBF,&H24,&H00 : '0034 MOV DI,0024 ;ES:DI -> keyboard interrupt vector
' &HB8,&H56,&H00 : '0037 MOV AX,0056 ;AX = Offset of new handler from CS
' &HFA : '003A CLI ;Disable interrupts
' &HAB : '003B STOSW ;\
' &H89,&HD8 : '003C MOV AX,BX ; } Change keyboard interrupt vector
' &HAB : '003E STOSW ;/ to point to new handler
' &HFB : '003F STI ;Enable interrupts
' &H1F : '0040 POP DS ;Restore DS for QBASIC
' &HCB : '0041 RETF ;
' &H1E : '0042 PUSH DS ;UNINSTALL INTERRUPT save DS for QBASIC
' &H31,&HC0 : '0043 XOR AX,AX ;\
' &H8E,&HC0 : '0045 MOV ES,AX ; } ES:DI -> keyboard interrupt vector
' &HBF,&H24,&H00 : '0047 MOV DI,0024 ;/
' &HBE,&H14,&H00 : '004A MOV SI,0014 ;\
' &H0E : '004D PUSH CS ; } DS:SI -> address of old handler
' &H1F : '004E POP DS ;/
' &HFC : '004F CLD ;Increment SI, DI on string moves
' &HFA : '0050 CLI ;Disable interrupts
' &HA5 : '0051 MOVSW ;\
' &HA5 : '0052 MOVSW ;/ Change interrupt vector
' &HFB : '0053 STI ;Enable interrupts
' &H1F : '0054 POP DS ;Restore DS for QBASIC
' &HCB : '0055 RETF ;
' &HFB : '0056 STI ;INTERRUPT HANDLER enable interrupts
' &H9C : '0057 PUSHF ;Save flags
' &H50 : '0058 PUSH AX ;Save registers
' &H53 : '0059 PUSH BX ;
' &H51 : '005A PUSH CX ;
' &H52 : '005B PUSH DX ;
' &H1E : '005C PUSH DS ;
' &H56 : '005D PUSH SI ;
' &H06 : '005E PUSH ES ;
' &H57 : '005F PUSH DI ;
' &HE4,&H60 : '0060 IN AL,60 ;AL = Scan code
' &HB4,&H01 : '0062 MOV AH,01 ;Assume it's a make code
' &HA8,&H80 : '0064 TEST AL,80 ;
' &H74,&H04 : '0066 JZ 006C ÚÄÄÄ;If it's not a break code then jump
' &HB4,&H00 : '0068 MOV AH,00 ³ ; It's a break code
' &H24,&H7F : '006A AND AL,7F ³ ; key index = code AND 127
' &HD0,&HE0 : '006C SHL AL,1 ÀÄÄ>;\
' &H88,&HC3 : '006E MOV BL,AL ; } BX = key index * 2
' &HB7,&H00 : '0070 MOV BH,00 ;/
' &HB0,&H00 : '0072 MOV AL,00 ;
' &H2E : '0074 CS: ;
' &H03,&H1E,&H12,&H00 : '0075 ADD BX,[0012] ;BX = BX + offset of matrix
' &H2E : '0079 CS: ;
' &H8E,&H1E,&H10,&H00 : '007A MOV DS,[0010] ;DS = segment of matrix
' &H86,&HE0 : '007E XCHG AH,AL ;
' &H89,&H07 : '0080 MOV [BX],AX ;Store key state
' &HE4,&H61 : '0082 IN AL,61 ;Interrupt Clean up
' &H0C,&H82 : '0084 OR AL,82 ;
' &HE6,&H61 : '0086 OUT 61,AL ;
' &H24,&H7F : '0088 AND AL,7F ;
' &HE6,&H61 : '008A OUT 61,AL ;
' &HB0,&H20 : '008C MOV AL,20 ;
' &HE6,&H20 : '008E OUT 20,AL ;
' &H5F : '0090 POP DI ;Restore registers
' &H07 : '0091 POP ES ;
' &H5E : '0092 POP SI ;
' &H1F : '0093 POP DS ;
' &H5A : '0094 POP DX ;
' &H59 : '0095 POP CX ;
' &H5B : '0096 POP BX ;
' &H58 : '0097 POP AX ;
' &H9D : '0098 POPF ;Restore flags
' &HCF : '0099 IRET ;Exit interrupt

SUB KEYTEST : 'Helps you find new keycodes
' Usage:
' CALL KEYTEST or KEYTEST
' This will show all 128 keycodes & their statuses.
' Press & hold a key & a 1 will appear somewhere.
' The number that the 1 is by will be the keycode
' for that key. Simple!
SCREEN 0
CLS
Z = MULTIKEY(-1)
DO
X = 1
Y = 1
FOR I = 1 TO 128
TEST = MULTIKEY(I)
LOCATE Y, X
PRINT USING "## =###"; TEST; I
IF Y < 23 THEN
Y = Y + 1
ELSE
Y = 1
X = X + 9
END IF
NEXT I
LOOP WHILE MULTIKEY(1) = 0
Z = MULTIKEY(-2)
END SUB

FUNCTION MULTIKEY (T)
' Usage:
' X = MULTIKEY(T)
' where t can equal -1,-2, and 1-128
' t = -1: IMPORTANT!!! Make sure you pass this value to
' the function before -2 and 1-128! It turns the
' interrupt on so you can start reading keys.
' Returns: nothing
' t = -2: EXTREMELY IMPORTANT!!!!!!!!
' ALWAYS pass this before you end your program!
' If you don't, your computer won't be able to
' read your keyboard & you'll have to reset!
' i.e., CTRL-ALT-DEL won't work!!
' Returns: nothing
' t = keycode (1-128): Returns status of a key.
' Returns: 1 or 0 where
' 1 = pressed
' 0 = unpressed
'
STATIC kbcontrol%(), kbmatrix%(), Firsttime, StatusFlag
IF Firsttime = 0 THEN 'Initalize
DIM kbcontrol%(128)
DIM kbmatrix%(128)
code$ = ""
code$ = code$ + "E91D00E93C00000000000000000000000000000000000000000000000000"
code$ = code$ + "00001E31C08ED8BE24000E07BF1400FCA5A58CC38EC0BF2400B85600FAAB"
code$ = code$ + "89D8ABFB1FCB1E31C08EC0BF2400BE14000E1FFCFAA5A5FB1FCBFB9C5053"
code$ = code$ + "51521E560657E460B401A8807404B400247FD0E088C3B700B0002E031E12"
code$ = code$ + "002E8E1E100086E08907E4610C82E661247FE661B020E6205F075E1F5A59"
code$ = code$ + "5B589DCF"
DEF SEG = VARSEG(kbcontrol%(0))
FOR I% = 0 TO 155 ' Load ASM
d% = VAL("&h" + MID$(code$, I% * 2 + 1, 2))
POKE VARPTR(kbcontrol%(0)) + I%, d%
NEXT I%
I& = 16 ' I think this stuff connects the interrupt with kbmatrix%()
N& = VARSEG(kbmatrix%(0)): l& = N& AND 255: h& = ((N& AND &HFF00) \ 256): POKE I&, l&: POKE I& + 1, h&: I& = I& + 2
N& = VARPTR(kbmatrix%(0)): l& = N& AND 255: h& = ((N& AND &HFF00) \ 256): POKE I&, l&: POKE I& + 1, h&: I& = I& + 2
DEF SEG
Firsttime = 1
END IF
SELECT CASE T
CASE -1
IF StatusFlag = 0 THEN
DEF SEG = VARSEG(kbcontrol%(0))
CALL ABSOLUTE(0) ' Run interrupt
DEF SEG
StatusFlag = 1
END IF
CASE -2
IF StatusFlag = 1 THEN
DEF SEG = VARSEG(kbcontrol%(0)) ' Turn off interrupt
CALL ABSOLUTE(3)
DEF SEG
StatusFlag = 0
END IF
CASE 1 TO 128
MULTIKEY = kbmatrix%(T) ' Return status
CASE ELSE
MULTIKEY = 0 ' User Supidity Error
END SELECT
END FUNCTION

SUB TheDemo : ' Shows how this works in a typical application
' Use arrows to turn & accelerate
' Press space to come to a total stop
' Hit ESC to exit
Z = MULTIKEY(-1) ' Initalize ASM & hook interrupt
SCREEN 12
CLS
X = 320
Y = 240
cPI = (3.141592654# / 180)
ANGLE = 0
RADIUS = 5
SPEED = .2
DO
IF MULTIKEY(77) THEN ANGLE = ANGLE - 7 ' Left
IF MULTIKEY(75) THEN ANGLE = ANGLE + 7 ' Right
IF MULTIKEY(72) THEN ' Up
VX = VX + (SIN(cPI * ANGLE) * SPEED)
VY = VY + (COS(cPI * ANGLE) * SPEED)
END IF
IF MULTIKEY(80) THEN ' Down
VX = VX - (SIN(cPI * ANGLE) * SPEED)
VY = VY - (COS(cPI * ANGLE) * SPEED)
END IF
IF MULTIKEY(57) THEN ' Space
VX = 0
VY = 0
END IF
IF ANGLE > 360 THEN ' Wrap-around angle
ANGLE = 0 + (ANGLE - 360)
END IF
IF ANGLE < 0 THEN
ANGLE = 360 - (0 + ANGLE)
END IF
IF X < 0 + RADIUS THEN VX = -VX ' Bounce limits
IF X > 640 - RADIUS THEN VX = -VX
IF Y < 0 + RADIUS THEN VY = -VY
IF Y > 480 - RADIUS THEN VY = -VY
X = X + VX ' Move it
Y = Y + VY
X2 = X + SIN(cPI * ANGLE) * RADIUS ' White dot calc
Y2 = Y + COS(cPI * ANGLE) * RADIUS ' ditto
VX = VX * .998 ' Friction
VY = VY * .998 ' ditto
CIRCLE (XX, YY), RADIUS, 0 ' Erase
PSET (XX2, YY2), 0
PSET (XX, YY), 0
CIRCLE (X, Y), RADIUS, 4 ' Draw
PSET (X2, Y2), 15
PSET (X, Y), 4
XX = X: YY = Y: YY2 = Y2: XX2 = X2
WAIT &H3DA, 8 ' Wait to vert. retarce
WAIT &H3DA, 8, 8
LOOP UNTIL MULTIKEY(1) = 1 ' Hit ESC to exit
Z = MULTIKEY(-2) 'Unhook interrupt
END SUB



and yeah if i didnt mention that its not mine, so its not its a demo somehow i found it.

[kici]

well thats actually the same webpage which that guy was helping u there,,, oh sorry didnt know, i just kept it and i just noticed that

[Mikrondel]

Hello kici

Welcome to the forum. Help is appreciated, but in this case Kyle isn't very likely to come and read your response such a long time after.

I have lots of knowledge of QB, C/C++, PHP, HTML/CSS/JS, networking, Linux, Windows, and lots of other areas. Though for non-QB stuff, the General Board is probably a better place.

Hope to see you around,

Mikrondel